Angoli orientati e definizione delle funzioni goniometriche

Lorenzo Roi (luglio 2022)

Presentazione

In questo notebook intendiamo dapprima introdurre la misura di un angolo orientato estendendola all'insieme dei reali e successivamente definiamo le funzioni goniometriche del seno, coseno e tangente studiandone i grafici e le periodicità.

Codice e funzioni utilizzate

Le istruzioni seguenti, compatibili con Mathematica 8 o con il CDF Player, vanno caricate prima di procedere al calcolo delle celle di input di questo notebook.

SetOptions[Graphics, BaseStyle->{FontSize->9}];
SetOptions[Plot, BaseStyle->{FontSize->9}];
SetOptions[ListPlot, BaseStyle->{FontSize->9}];
SetOptions[ParametricPlot, BaseStyle->{FontSize->9}];
SetOptions[Manipulate, SaveDefinitions->True,ControlPlacement->Top];
(****************************)
(* traccia una spirale attorno all'origine per evidenziare l'angolo orientato, di color rosso se positivo, blu se negativo *)
angoloOrientato[α_,centro_:{0,0}]:=Show[If[α≠0,ParametricPlot[1/200 {Sign[t] t Cos[t],Sign[t] t Sin[t]} π+centro,{t,2 π Sign[α],Sign[α]2 π+α},Axes->False,PlotStyle->{Thick,If[Sign[α]==1,Red,Blue]}],ParametricPlot[1/200 {Sign[t] t Cos[t],Sign[t] t Sin[t]} π+centro,{t,0,0.0001},Axes->False,PlotStyle->{Thick,If[Sign[α]==1,Red,Blue]}]],Graphics[{{Gray,Circle[centro,1],Line[{{Cos[α],Sin[α]}+centro,centro}]},{PointSize[Medium],Point[{Cos[α],Sin[α]}+centro]}}],Epilog->{Text[Style["ampiezza α = "<>ToString[N[α]/π]<>"π",Bold,FontSize->12],{0.5,1.1}+centro,{-1,0}]},PlotRange->{{-1.2,1.5},{-1.2,1.2}},Axes->True,AxesOrigin->Automatic,ImageSize->400];
(****************************)
angoloOrientatoNoTesto[α_,centro_:{0,0}]:=Show[If[α≠0,ParametricPlot[1/200 {Sign[t] t Cos[t],Sign[t] t Sin[t]} π+centro,{t,2 π Sign[α],Sign[α]2 π+α},Axes->False,PlotStyle->{Thick,If[Sign[α]==1,Red,Blue]}],ParametricPlot[1/200 {Sign[t] t Cos[t],Sign[t] t Sin[t]} π+centro,{t,0,0.0001},Axes->False,PlotStyle->{Thick,If[Sign[α]==1,Red,Blue]}]],Graphics[{{Gray,Circle[centro,1],Line[{{Cos[α],Sin[α]}+centro,centro}]},{PointSize[Medium],Point[{Cos[α],Sin[α]}+centro]}}],PlotRange->{{-1.2,1.5},{-1.2,1.2}},Axes->True,AxesOrigin->Automatic];
(****************************)
(*** traccia il triangolo rettangolo giallo e i vettori sui cateti ***)
costruzione[α_,funGonio_String]:=Module[{pP,pQ,pO},
pP={Cos[α],Sin[α]};pQ={Cos[α],0};pO={0,0};Graphics[{{Yellow,Polygon[{pO,pQ,pP}]},{If[α>0,Red,Blue],Disk[pO,.2,If[α≥0,{0,α},{α,0}]]},{{Gray,Circle[]},Line[{pP,pO}]},
{{Thick,Switch[funGonio,"seno",Blue,"coseno",Gray,"tangente",Blue],Arrow[{pQ,pP}]},{Thick,Switch[funGonio,"seno",Gray,"coseno",Blue,"tangente",Blue],Arrow[{pO,pQ}]}}}]];
(****************************)
vertici[α_,stile___]:=Module[{pP,pQ,pO},pP={Cos[α],Sin[α]};pQ={Cos[α],0};pO={0,0};Graphics[{Text[Style["O",stile],pO,{1,1}],Text[Style["Q",stile],pQ,{0,1}],Text[Style["P",stile],pP,{0,-1}]}]];
(****************************)
geometriaTangente[α_]:=Show[Graphics[{{Gray,Line[{{1,-5},{1,5}}]},{RGBColor[.85, .65, 0],Polygon[{{0,0},{1,0},{1,Tan[α]}}]},{Blue,Thick,Arrow[{{0,0},{1,0}}],Arrow[{{1,0},{1,Tan[α]}}]},{Text["A",{1.03,.05},{-1,0}],Text["B",{1.03,Tan[α]},{-1,0}]}}],costruzione[α,"tangente"],vertici[α],Axes->True,PlotRange->1.25,ImageSize->400];
(****************************)
parzialeSeno[α_]:=Graphics[{}]/;α==0;
parzialeSeno[α_]:=Plot[Sin[x],{x,0,α},PlotStyle->{Thick,Blue}]/;α≠0;
(****************************)
parzialeCoseno[α_]:=Graphics[{}]/;α==0;
parzialeCoseno[α_]:=Plot[Cos[x],{x,0,α},PlotStyle->{Thick,Blue}]/;α≠0;
(****************************)
parzialeTangente[α_,angMax_]:=Plot[Tan[x],{x,-angMax,α},PlotStyle->{Thick,Blue},Exclusions->Table[i,{i,-3/2π,3/2π,π/2}]];

Estensione delle ampiezze di un angolo

La misura dell'ampiezza di un angolo è comunemente espressa da un numero reale compreso nell'intervallo [0,2π]se espresso in radianti oppure, se intesa in gradi, la misura appartiene all'intervallo [0°,360°]. Come per i segmenti anche per gli angoli è comunque possibile introdurre una orientazione o verso e quindi assegnare valori positivi o negativi all'ampiezza corrispondente. 
Identificato quindi un lato dell'angolo (che è una semiretta) con il semiasse positivo delle x di un sistema cartesiano isometrico di origine O, potremo assegnare un verso all'angolo appena sia dato il secondo lato. Difatti, partendo dal semiasse positivo e muovendoci in verso antiorario fino ad incontrare l'altro lato, introduciamo la convenzione che associa all'ampiezza di quest'angolo un valore positivo. Se invece, sempre a partire dal semiasse positivo ci muoviamo in verso orario fino ad incontrare il secondo lato, l'ampiezza corrispondente dell'angolo in tal modo individuato verrà espressa da un valore negativo. Allora, per esempio, il seguente angolo è positivo

angoloOrientato[8π/10]

Figura 1

mentre quello rappresentato in fig. 2 è identificato da una misura dell'ampiezza di segno negativo: in termini geometrici tradizionali (cioè con ampiezze appartenenti agli intervalli ricordati sopra) la loro somma fornisce invece l'angolo giro cioè un'ampiezza di 360° oppure 2π.

angoloOrientato[-12/10π]

Figura 2

Come si vede, possiamo quindi individuare i due angoli nei quali viene suddiviso il piano, il primo (convesso in questo esempio) con una misura positiva, il secondo (nell'esempio, concavo) con una misura negativa. Poiché è possibile che il secondo lato dell'angolo ripassi più volte sul semiasse positivo delle ascisse ossia per il lato origine cioè "ruoti" attorno all'origine del sistema cartesiano, conveniamo di tener conto di tale eventualità nell'esprimere la misura dell'angolo in tal modo percorso. L'ampiezza dell'angolo potrà pertanto assumere qualsiasi valore positivo così come qualsiasi valore negativo. Difatti, ad ogni giro completo del secondo lato attorno all'origine O l'ampiezza dovrà aumentare di un valore pari a 2π (o 360°). L'animazione successiva mostra appunto come si debbano considerare angoli la cui misura sia maggiore di 2π

Manipulate[angoloOrientato[α],{{α,2.25π,Style["α ",Bold,FontSize->12]},0,4π,π/100}]

o minore di -2π.

Manipulate[angoloOrientato[α],{{α,-2.25π,Style["α ",Bold,FontSize->12]},0,-4π,π/100}]

In definitiva, la convenzione appena introdotta ci permette di associare ad un qualsiasi numero reale α un angolo orientato ossia un angolo con lato origine sul semiasse positivo delle x di un sistema cartesiano e la cui ampiezza è espressa da un valore positivo o negativo a seconda che si debba ruotare in verso antiorario o orario per raggiungere il secondo lato ruotando, se necessario, anche più volte attorno all'origine. In termini un po' più formali abbiamo stabilito la funzione

α∈ℝ ⟶ angolo orientato

che lega un numero reale ad un angolo orientato. Se al sistema cartesiano associamo pure una circonferenza γ di raggio dato qualsiasi e di centro nell'origine, il secondo lato determina un punto P (ed uno solo) di intersezione con γ cosicché in corrispondenza di un valore reale di α esiste un solo P∈γ. La corrispondenza qualitativa precedente si specifica quindi in

α∈ℝ ⟶ P∈γ.

È immediato notare che tale funzione non può essere iniettiva: difatti è sufficiente riprendere il primo esempio (fig.1 e fig. 2) per vedere come al medesimo punto P (nelle figure evidenziato dal cerchietto nero) si possano associare già due valori distinti di α. Difatti in generale, se α individua un determinato angolo e quindi un punto P, viceversa questo stesso punto può essere individuato dall'insieme (numerabile) di valori α+2k π con k∈ℤ: ciascuno di questi valori differisce da α per un multiplo (positivo o negativo) di 2π, multiplo che descrive il numero di rotazioni complete attorno all'origine necessarie per "raggiungere" α+2k π a partire dallo stesso α.

Definizione della funzione seno di un angolo

Ad un sistema cartesiano isometrico Oxy associamo quindi una circonferenza γ di raggio r assegnato e sia α l'ampiezza di un angolo qualsiasi (nelle figure verrà considerato r=1: in tal caso la circonferenza viene identificata come la circonferenza goniometrica). Come detto, il secondo lato di tale angolo individua un punto P su γ: sia Q la proiezione sull'asse delle x di P, R quella sull'asse delle y.
Definiamo seno dell'angolo α il valore del rapporto

Definizione del seno di un angolo α

sen(α)=(QP/OP)

dove QP (fig. 3) rappresenta la misura del segmento orientato di estremi Q e P (o anche la componente del vettore OP sull’asse y). Se OP=1 è pari anche all'ordinata del punto P. QP rappresenta quindi un valore che appartiene all'intervallo [-r,r]. OP è invece la lunghezza del segmento di estremi O e P oppure il modulo del vettore OP (oppure, come detto, il raggio r della circonferenza γ cui appartiene il punto P). OP è espresso pertanto da un numero positivo (r>0) e al variare di P su γ rimane costante.

Show[costruzione[50Degree,"seno"],vertici[50Degree,Red,Bold,FontSize->13],Axes->True,PlotRange->1.2,ImageSize->400]

Figura 3

Variazione della funzione seno

Per come abbiamo esteso l'insieme delle ampiezze di un angolo riusciamo ad associare ad ogni valore reale α un punto P sulla circonferenza e quindi siamo pure in grado di calcolare il rapporto tra QP e OP ossia il valore di sen(α). In tal modo disponiamo di una funzione che associa ad ogni α reale il valore y=sen(α).

α∈ℝ ⟶ y=sen(α)

Ci chiediamo ora quale siano le caratteristiche di tale funzione, in particolare il suo grafico e il suo codominio. Faremo pertanto variare α su un insieme di valori reali [0,2π] analizzando, dapprima qualitativamente, le variazioni del segmento orientato QP e del suo rapporto con OP.

Manipulate[Show[costruzione[α,"seno"],vertici[α],Graphics[{{Text["sen("<>ToString[
PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Sin[α]]],{1,1},{-1,0}]}}],AspectRatio->Automatic,Axes->True,PlotRange->{{-1.2,1.6},{-1.2,1.2}},ImageSize->450],{{α,0.28π,Style["α ",Bold,FontSize->12]},0,2π,π/100}]

L'animazione ci fa comprendere come all'aumentare di α da 0 al valore di (π/2) il seno aumenti raggiungendo il suo valore massimo, +1, in corrispondenza di (π/2). Per valori maggiori sen(α) diminuisce passando per il valore nullo quando α=π e assumendo valori negativi per π≤α≤(3/2)π. Infine raggiunto il valore minimo sen((3/2)π)=-1, la funzione ricomincia poi a crescere fino 2π. Il codominio appare quindi essere l'intervallo [-1,1].

Grafico della funzione seno e periodicità

Per visualizzare un grafico della funzione seno al variare di α è comunque necessario un approccio più preciso. Riporteremo quindi i valori dell'angolo α sull'asse della variabile indipendente di un sistema cartesiano e, in corrispondenza, associamo all'ordinata il valore di sen(α). Per facilitare il riconoscimento del legame tra angolo e valore dell'ascissa riportiamo entrambi con lo stesso colore (rosso) mentre per mostrare che l'ordinata è effettivamente il valore del seno corrispondente tracciamo la circonferenza goniometrica (quindi OP=1 e sen(α)=QP/1=QP=(Subscript[y, P])) traslata di una unità nel verso delle ascisse negative per non interferire con il grafico. Abbiamo pertanto

Manipulate[Show[angoloOrientatoNoTesto[α,{-1,0}],Plot[Sin[x],{x,0,2π},PlotStyle->LightGray],Graphics[{{Gray,Line[{{Cos[α]-1,0},{Cos[α]-1,Sin[α]},{α,Sin[α]},{α,0}}],Line[{{-1,-1},{-1,1}}]},{Red,Thick,Line[{{0,0},{α,0}}]},{PointSize[Medium],Point[{α,Sin[α]}]},{Text[Style["sen("<>ToString[PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Sin@α]],Bold,FontSize->12],{4,0.75},{-1,0}]}}],parzialeSeno[α],PlotRange->{{-2.05,2π},{-1.1,1.1}},Ticks->{{π/2,π,3π/2,2π},Automatic},ImageSize->{750,250}],{{α,.28π,Style["α ",Bold,FontSize->12]},0,2π,π/200}]

Il grafico emerge ora con immediatezza e ci permette di riconoscere con facilità gli intervalli dove sen(α) è crescente [0,(π/2)[⋃](3/2)π,2π] e dove invece risulta decrescente ](π/2),(3/2)π[. Appaiono confermati pure i valori dell'angolo in corrispondenza dei quali il seno assume i valori massimo, sen((π/2))=1, e minimo sen((3/2)π)=-1 così come il codominio [-1,1].

Possiamo infine dedurre un'altra importante proprietà della funzione seno e del suo grafico. Se estendiamo α a valori maggiori di 2π la configurazione geometrica del triangolo OQP (fig. 3) rimane inalterata e ciò evidentemente a seguito del modo con cui abbiamo esteso il dominio degli angoli. Di conseguenza la funzione sen(α) riprende gli stessi valori ma in corrispondenza di angoli diversi che differiscono dai precedenti per multipli di 2π. L'animazione seguente mostra quanto avviene per angoli nell'intervallo [0,4π].

Manipulate[Show[angoloOrientatoNoTesto[α,{-1,0}],Plot[Sin[x],{x,0,4π},PlotStyle->LightGray],Graphics[{Line[{{Cos[α]-1,0},{Cos[α]-1,Sin[α]},{α,Sin[α]},{α,0}}],{Red,Thick,Line[{{0,0},{α,0}}]},{PointSize[Medium],Point[{α,Sin[α]}]},{Text[Style["sen("<>ToString[PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Sin@α]],Bold,FontSize->12],{4,1.2},{-1,0}]}}],parzialeSeno[α],PlotRange->{{-2,4π},{-1.2,1.2}},Ticks->{Range[1/2,4,1/2]π,Automatic},ImageSize->{750,150}],{{α,.28π ,Style["α ",Bold,FontSize->12]},0,4π,π/200}]

Funzioni con tale proprietà ossia tali da assumere i medesimi valori in corrispondenza di valori della variabile indipendente che differiscano per un certo valore T o suoi multipli interi, nel nostro caso T=2π, verranno dette funzioni periodiche di periodo T. Per queste la definizione generale che si dà è

Definizione di funzione periodica

La funzione f è periodica con periodo T se e solo se

∀ x ∈ Dom(f),    f(x+kT) = f(x)     con   k = 0, ±1, ±2,...

Block[{α=π/4},
Show[Plot[Sin[x],{x,-2π,3π},LabelStyle->Directive[FontFamily->"Helvetica"],Ticks->{Range[-2,3,1/2]π,{-1,1}},PlotStyle->Blue],Graphics[{Red,Line[{{-2π+α,0},{-2π+α,Sin[α]},{α,Sin[α]},{α,0},{α,Sin[α]},{α+2π,Sin[α]},{α+2π,0},{α+2π,Sin[α]},{3π,Sin[α]}}]}],Graphics[{Red,Text[Style["α-2π",FontFamily->"Helvetica"],{α-2π,-.25}],Text[Style["α",FontFamily->"Helvetica"],{α,-.25}],Text[Style["α+2π",FontFamily->"Helvetica"],{α+2π,-.25}]}],AspectRatio->Automatic,ImageSize->{600,100}]]

Figura 4

La figura 4 mette in evidenza che, pur essendo α≠α-2π≠α+2π ecc. le uguaglianze

sen(α)=sen(α-2π)=sen(α+2π)= ....

sono, per la funzione seno, certamente vere. Pertanto in generale, vale l'identità

sen(α) = sen(α+2π k)      ∀α∈ℝ ∧ k∈ℤ

e possiamo concludere che la funzione seno rientra nella definizione data sopra ed è quindi periodica con periodicità T=2π.

Definizione della funzione coseno di un angolo

Per quanto visto circa la funzione seno, la definizione della seconda funzione goniometrica fondamentale cioè del coseno di un angolo, discende abbastanza naturale. Si pone pertanto

Definizione del coseno di un angolo α

cos(α)=(OQ/OP)

essendo OQ il segmento orientato (o componente "orizzontale" del vettore OP) che individua l'ascissa di P nella circonferenza γ di centro O e raggio OP (fig. 5).

Show[costruzione[50Degree,"coseno"],vertici[50Degree,Red,Bold,FontSize->13],Axes->True,PlotRange->1.2,ImageSize->400]

Figura 5

Variazione del coseno

Un'analisi qualitativa dell'andamento della funzione y=cos(α) per  α∈[0,2π] basata sull'animazione seguente

α∈ℝ ⟶ y=cos(α)

permette di individuare già alcune interessanti caratteristiche.

Manipulate[Show[costruzione[α,"coseno"],vertici[α],Graphics[{{Text["cos("<>ToString[
PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Cos[α]]],{1,1},{-1,0}]}}],AspectRatio->Automatic,Axes->True,PlotRange->{{-1.2,1.6},{-1.2,1.2}},ImageSize->500],{{α,.28π,Style["α ",Bold,FontSize->12]},0,2π,π/100}]

Riconosciamo difatti che tale funzione risulta positiva quando x∈[0,(π/2)[ ⋃ ](3/2)π,2π] e in particolare assume il valore +1 in corrispondenza di α=0 mentre vale -1 quando α=π. Questi rappresentano pure il valore massimo e, rispettivamente, minimo del codominio che pertanto è l'intervallo [-1,1]. Appare inoltre decrescente in ]0,π[ e crescente in ]π,2π[ mentre risulta cos((π/2))=cos((3/2)π)=0.

Grafico della funzione coseno e periodicità

Per ottenere il grafico del coseno procediamo nello stesso modo seguito per il seno: trasliamo (ma solo a livello grafico) la circonferenza goniometrica di un'unità negativa sull'asse orizzontale onde non interferire con lo sviluppo del grafico e codifichiamo con lo stesso colore (rosso) l'angolo α percorso attorno all'origine e l'ascissa del punto (mobile) sul grafico del coseno. Poiché OP=1 la definizione si riduce a cos(α)=OQ=(Subscript[x, P]) cioè il coseno risulta pari all'ascissa del punto (di color nero) sulla circonferenza goniometrica e individuato dal secondo lato dell'angolo. Dato che intendiamo riportare in ordinata tale valore, eseguiamo una simmetria rispetto alla bisettrice del I e III quadrante, simmetria rappresentata nell'animazione seguente dal segmento tratteggiato: in tal modo il punto di color verde possiede ordinata pari a cos(α). Con tale costruzione il punto mobile che descrive il grafico ha coordinate (α,cos(α)): ne studiamo l'andamento per α∈[0,2π].

Manipulate[Show[angoloOrientatoNoTesto[α,{-1,0}],Plot[Cos[x],{x,0,2π},PlotStyle->LightGray],Graphics[{{Gray,Line[{{Cos[α]-1,0},{Cos[α]-1,Sin[α]}}],Line[{{-1,-1},{-1,1}}],Line[{{-1,Cos[α]},{α,Cos[α]},{α,0}}]},{Dashed,Line[{{Cos[α]-1,0},{-1,Cos[α]}}]},{Green,Thick,Point[{-1,Cos[α]}]},{Red,Thick,Line[{{0,0},{α,0}}]},{PointSize[Medium],Point[{α,Cos[α]}]},Text[Style["cos("<>ToString[PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Cos@α]],Bold,FontSize->12],{π,0.75},{-1,-1}]}],parzialeCoseno[α],PlotRange->{{-2.05,2π},{-1.2,1.2}},Ticks->{{π/2,π,3π/2,2π},Automatic},ImageSize->{750,250}],{{α,.28π,Style["α ",Bold,FontSize->12]},0,2π,π/200}]

Per angoli esterni all'intervallo [0,2π] la configurazione geometrica appena studiata si ripete inalterata suggerendo la periodicità pure della funzione coseno.

Manipulate[Show[angoloOrientatoNoTesto[α,{-1,0}],Plot[Cos[x],{x,0,4π},PlotStyle->LightGray],Graphics[{{Gray,Line[{{Cos[α]-1,0},{Cos[α]-1,Sin[α]}}],Line[{{-1,-1},{-1,1}}],Line[{{-1,Cos[α]},{α,Cos[α]},{α,0}}]},{Dashed,Line[{{Cos[α]-1,0},{-1,Cos[α]}}]},{Green,Thick,Point[{-1,Cos[α]}]},{Red,Thick,Line[{{0,0},{α,0}}]},{PointSize[Medium],Point[{α,Cos[α]}]},Text[Style["cos("<>ToString[PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Cos@α]],Bold,FontSize->12],{2,.9},{-1,-1}]}],parzialeCoseno[α],PlotRange->{{-2,4π},{-1.1,1.1}},Ticks->{Range[1/2,4,1/2]π,Automatic},ImageSize->{650,150}],{{α,.28π,Style["α ",Bold,FontSize->12]},0,4π,π/200}]

Valgono di conseguenza le seguenti identità (fig. 6)

cos(α)=cos(α-2π)=cos(α+2π) = ....

Block[{α=π/4},
Show[Plot[Cos[x],{x,-2π,3π},LabelStyle->Directive[FontFamily->"Helvetica"],Ticks->{Range[-2,3,1/2]π,{-1,1}},PlotStyle->Blue],Graphics[{Red,Line[{{-2π+α,0},{-2π+α,Cos[α]},{α,Cos[α]},{α,0},{α,Cos[α]},{α+2π,Cos[α]},{α+2π,0},{α+2π,Cos[α]},{3π,Cos[α]}}]}],Graphics[{Red,Text[Style["α-2π",FontFamily->"Helvetica"],{α-2π,-.25}],Text[Style["α",FontFamily->"Helvetica"],{α,-.25}],Text[Style["α+2π",FontFamily->"Helvetica"],{α+2π,-.25}]}],AspectRatio->Automatic,ImageSize->{600,100}]]

Figura 6

casi particolari della più generale identità

cos(α)=cos(α+2k π)         ∀α∈ℝ ∧ k∈ℤ

e che stabilisce la periodicità della funzione coseno con periodo T=2π.

Definizione della funzione tangente di un angolo e periodicità

Sempre in riferimento alla circonferenza γ associata ad un sistema cartesiano di origine O (fig. 7), definiamo la tangente di un angolo α come il rapporto

Definizione della tangente di un angolo α

tg(α)=(QP/OQ)

dove entrambi i segmenti coinvolti vanno interpretati come segmenti orientati ossia come le componenti del vettore OP.

Show[costruzione[50Degree,"tangente"],vertici[50Degree,Red,Bold,FontSize->13],Axes->True,PlotRange->1.2,ImageSize->400]

Figura 7

Da tale definizione discende immediatamente che la tangente non è definita quando OQ=0: i valori di α che individuano le posizioni del punto P con ascissa nulla sono: α=(π/2)+2k π ∨ α=-(π/2)+2k π che si possono riassumere in α=(π/2)+k π. Pertanto il dominio della funzione tangente è l'insieme

α∈ℝ-{(π/2)+k π, k∈ℤ} ⟶ y=tg(α)

Poiché inoltre si può dividere numeratore e denominatore del secondo membro della definizione per OP, la tangente si può riscrivere identicamente come

tg α=(QP/OQ)=((QP/OP)/(OQ/OP))=((sen α)/(cos α))

non appena si siano tenute presenti le definizioni di sen(α) e cos(α). Ne segue che tg(α) risulta pure definita dal rapporto del seno e del coseno del medesimo angolo.

Periodicità

Una seconda importante proprietà discende sempre dalla definizione. Per dimostrarla analizziamo la configurazione geometrica che si presenta quando si considerino angoli che differiscono per π: per esempio, in figura 8, all'angolo α=50° (in rosso) si associ l'angolo 50°+180°=230° (in verde).

Manipulate[Block[{β},β=π+α;
pP={Cos[α],Sin[α]};pQ={Cos[α],0};pO={0,0};pR={Cos[β],Sin[β]};pS={Cos[β],0};
Show[Graphics[{{Yellow,Polygon[{pO,pQ,pP}],Polygon[{pO,pS,pR}]},{Green,Disk[pO,.3,{0,β}]},{Red,Disk[pO,.2,{0,α}]},{Gray,Circle[],Line[{pP,pO,pR}]},
{Blue,Thick,Arrow[{pO,pQ}],Arrow[{pQ,pP}],Arrow[{pO,pS}],Arrow[{pS,pR}]},
{Text["O",pO,{1,1}],Text["Q",pQ,{0,1}],Text["P",pP,{0,-1}],Text["S",pS,{0,-1}],Text["R",pR,{0,1}]}}],AspectRatio->Automatic,Axes->True,PlotRange->{{-1.2,1.5},{-1.2,1.2}}]],{{α,50 Degree,Style["α ",Bold,FontSize->12]},0,π}]

Figura 8

È evidente che i triangoli rettangoli △OQP e △OSR sono congruenti (∠ROS=∠POQ) ma che OS=-OQ e SR=-QP. Pertanto la tangente dell'angolo α+π che, per definizione, è

tg (α+π)=(SR/OS)

si può riscrivere come

tg (α+π)=(SR/OS)=((-QP)/(-OQ))=(QP/OQ)=tg α

Poiché tale relazione rimane valida qualsiasi sia l'angolo α potremo studiare la funzione tangente per valori appartenenti all'intervallo aperto ]-(π/2),(π/2)[ e poi estenderla, in base ad essa, in ] (π/2),(3/2)π[. Ma più importante appaiono due osservazioni:

la prima consiste nel tener conto che ad α e agli angoli che differiscono da esso per multipli pari di π, α+2 k π, si può associare la medesima configurazione (e ciò, come oramai sappiamo, equivale a k rotazioni complete attorno all'origine) per cui, di conseguenza, risulta tg(α)=tg(α+2 k π).

Seconda osservazione: a α+π si possono associare i valori (α+π)+2 k π=α+(2k+1)π tali da differire da α per multipli dispari di π (difatti 2k+1 è un numero dispari se k∈ℤ) e pure questi, per quanto dimostrato sopra, conducono ad una configurazione geometrica che fornisce lo stesso valore della tangente.

In definitiva qualsiasi sia il multiplo di π (pari o dispari) che lega α con α+k π, risulta valida l'identità

tg(α)=tg(α+k π)             ∀α∈ℝ-{(π/2)+kπ}   ∧   k∈ℤ.

Quest'ultima indentità stabilisce la periodicità della funzione tangente che pertanto, diversamente dal seno e coseno, possiede un periodo T=π.

Grafico della funzione tangente

Per lo studio del grafico della tangente in funzione di α manca ancora un elemento che ci permetterà di disporre di un significato più intuitivo e diretto del rapporto dato nella definizione. Costruiamo a tale scopo la retta tangente nel punto A(1,0) alla circonferenza goniometrica (fig. 9) e prolunghiamo il secondo lato dell'angolo fino ad intersecare questa retta. Sia B il loro punto di intersezione.

geometriaTangente[50Degree]

Figura 9

Data la similitudine tra △OQP∼△OAB e il fatto che OQ e OA siano concordi come QP e AB, risulta

tg α=(QP/OQ)=(AB/OA)=(AB/1)=AB

dove si è considerato che nella circonferenza goniometrica OA=1. Possiamo pertanto reinterpretare la tg(α) come la lunghezza del segmento orientato AB oppure anche come l'ordinata del punto B (oppure come la componente "verticale" del vettore OB). È ora immediato rappresentarci qualitativamente la variazione della tangente in funzione dell'angolo: a partire da -(π/2)(dove non è definita) all'aumentare di α aumenta pure la tangente che risulta un valore negativo per ]-(π/2),0[. È poi tg(0)=0 e quindi la funzione assume valori positivi sempre maggiori quando α, aumentando, si avvicina a (π/2).

Manipulate[Show[geometriaTangente[α],Graphics[{Text[Style["tg("<>ToString[N[α]/Degree]<>"°) = "<>ToString[N[Tan[α]]],Bold,FontSize->12],{-1.5,2.5},{-1,1}]}],PlotRange->{Automatic,{-2.8,2.8}},Ticks->{{-1,1},Automatic}],{{α,50 Degree,Style["α ",Bold,FontSize->12]},-70 Degree, 70 Degree}]

Sfruttando l'interpretazione precedente possiamo ottenere un grafico più preciso non appena si disponga in ascissa l'angolo α in modo del tutto analogo a quanto fatto per le funzioni seno e coseno. In ordinata poniamo quindi tg(α) cioè, geometricamente, riportiamo il segmento orientato AB. Per riconoscere più facilmente tale costruzione riportiamo in colore verde il punto B della precedente discussione e, in tratteggio, la retta tangente in (1,0) alla circonferenza goniometrica.

Manipulate[estremoSup=74Degree;Show[angoloOrientatoNoTesto[α],Plot[Tan[x],{x,-estremoSup,estremoSup},PlotStyle->LightGray],parzialeTangente[α,estremoSup+.001],Graphics[{{Dashed,Line[{{1,-5},{1,5}}]},Line[{{Cos[α],0},{Cos[α],Sin[α]},{1,Tan[α]}}],Line[{{α,0},{α,Tan[α]},{1,Tan[α]}}],{Green,PointSize[Medium],Point[{1,Tan[α]}]},Line[{{π/2,-3.5},{π/2,3.5}}],Line[{{-π/2,-3.5},{-π/2,3.5}}],{If[Sign[α]==1,Red,Blue],Thick,Line[{{0,0},{α,0}}]},{PointSize[Medium],Point[{α,Tan[α]}]},Text[Style["tg("<>ToString[PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[N[Tan@α]],Bold,FontSize->12],{-1.1,3.1},{-1,-1}]}],PlotRange->{{-π/2,π/2},{-3.5,3.5}},Ticks->{{-π/2,π/2},Automatic};ImageSize->400],{{α,40 Degree,Style["α ",Bold,FontSize->12]},-estremoSup,estremoSup}]

Appare quindi che il grafico della tangente tra ]-(π/2),(π/2)[ è sempre crescente e possiede due asintoti verticali dati dalle rette x=±(π/2). Osserviamo inoltre che, se α si avvicina a (π/2) assumendo valori sempre inferiori di tale valore (o anche "da sinistra"), la tangente assume valori positivi sempre maggiori: esprimiamo tale andamento con la scrittura informale

α⟶(π/2)-                     tg α⟶+∞

Allo stesso modo se α si avvicina a -(π/2) essendo sempre maggiore di tale valore (o "da destra"), la tangente assume valori negativi sempre minori: informalmente esprimiamo ancora ciò con la scrittura

α⟶(-(π/2))+                     tg α⟶-∞

In base allo studio del grafico emerge pure il codominio di tale funzione: dato che il punto B (di color verde) può assumere qualsiasi posizione sulla retta tratteggiata, in corrispondenza la sua ordinata (cioè tg(α)) può assumere qualsiasi valore reale. Il codominio della funzione tangente coincide pertanto con ℝ.
Visualizziamo infine il grafico della tangente in insiemi più estesi di ]-(π/2),(π/2)[ così da rendere evidente la sua (già dimostrata) periodicità. Si tenga presente che in corrispondenza dei valori x= (π/2)+k π la funzione tangente non esiste (nella animazione seguente pertanto, gli asintoti x= (π/2)+k π non appartengono al grafico della tangente).

Manipulate[Show[angoloOrientatoNoTesto[α],Plot[Tan[x],{x,-2π,2π},Exclusions->Table[i,{i,-3/2π,3/2π,π/2}],PlotStyle->LightGray],parzialeTangente[α,2π+.001],Graphics[{{Gray,Table[Line[{{i,-4.5},{i,4.5}}],{i,-3/2π,3/2π,π}]},{Dashed,Line[{{1,-5},{1,5}}]},{Gray,Line[{{Cos[α],0},{Cos[α],Sin[α]},{1,Tan[α]}}],Line[{{α,0},{α,Tan[α]},{1,Tan[α]}}]},{Green,PointSize[Medium],Point[{1,Tan[α]}]},{If[Sign[α]==1,Red,Blue],Thick,Line[{{0,0},{α,0}}]},{PointSize[Medium],Point[{α,Tan[α]}]},Text[Style["tg("<>ToString[PaddedForm[N[α/π],{3,2}]]<>"π) = "<>ToString[Chop@N[Tan@α]],Bold,FontSize->12],{2,4},{-1,-1}]}],PlotRange->{{-2π,2π},{-4.5,4.5}},AspectRatio->Automatic,Ticks->{Range[-2,2,1/2]π,Automatic},ImageSize->500],{{α,.66π,Style["α ",Bold,FontSize->12]},-2π,2π}]